'/// CreateDefaultLighting: ver 1.0 for XSI 3.5+
'/// By Homam Bahnassi - In|Framez 2003
'--------------------------------------

set oRoot = ActiveProject.ActiveScene.Root

'-- Hide any lights available in the scene.
set oSceneLights = oRoot.FindChildren(,siLightPrimType)
for each oLight in oSceneLights
	oLight.Properties("visibility").parameters("viewvis").value = false
next

'-- Create three infinite lights & put them in a collection...
set oLights = CreateObject("XSI.Collection")
set oKeyLight = oRoot.AddLight( "LightInfinite", False ,"KeyLight" )
set oFillLight = oRoot.AddLight( "LightInfinite", False ,"FillLight" )
set oRimLight = oRoot.AddLight( "LightInfinite", False ,"RimLight" )
oLights.Add oKeyLight
oLights.Add oFillLight
oLights.Add oRimLight

'-- Set their rotations...
oKeyLight.rotx.value = -30
oKeyLight.roty.value = 30
oKeyLight.rotz.value = 0

oFillLight.rotx.value = 0
oFillLight.roty.value = -75
oFillLight.rotz.value = 0

oRimLight.rotx.value = 15
oRimLight.roty.value = -210
oRimLight.rotz.value = 0

'-- Set their color values...
oKeyLight.Shaders(0).parameters("color").red.value = 1.0
oKeyLight.Shaders(0).parameters("color").green.value = 0.95
oKeyLight.Shaders(0).parameters("color").blue.value = 0.75

oFillLight.Shaders(0).parameters("color").red.value = 0.9
oFillLight.Shaders(0).parameters("color").green.value = 1.0
oFillLight.Shaders(0).parameters("color").blue.value = 1.0

oRimLight.Shaders(0).parameters("color").red.value = 0.8
oRimLight.Shaders(0).parameters("color").green.value = 0.825
oRimLight.Shaders(0).parameters("color").blue.value = 0.875

'-- Add models for the lights...
set oLightsModel = oRoot.AddModel( oLights , "DefaultLights")
set oDispProp = oLightsModel.AddProperty ("Display Property")
oDispProp.wirecol.value = 47

'-- Hide rendering visiblity...
oKeyLight.Properties("visibility").parameters("rendvis").value = false
oFillLight.Properties("visibility").parameters("rendvis").value = false
oRimLight.Properties("visibility").parameters("rendvis").value = false

'Almost done...
logmessage "Default Lights Created Successfully..."